;(hc)nh-2d-jc
;avance-version
;2D HCNH (800 MHz)
;o2p = 56.0 ppm
;1) exclude Rance-Kay trick
;2) use maximum resolution for t1 including also period k
;3) water flip back and final watergate for water suppression

; Chugh and Hosur, Journal of Magnetic Resonance (2008) doi:10.1016/j.jmr.2008.07.022

;written by jc at 800 MHz

;$OWNER=guest
prosol relations =<triple>

#include <Avance.incl>
#include <Grad.incl>

;############# HNN suite of experiments #################
;p34 pulse makes this experiment selective for glycines/alanines/ser-threonines
;p34 = 200us for standard HSQC type spectra
;p34 = optimize around 325 us for alanines
;p34 = optimize around 650 us for ser-threonines with SPOFF20 = 1600 Hz (carrier for this pulse shifted to 64 ppm) 
;########################################################


;############### constant values ##############


"d4=1s/(cnst22*4)"                   ;cnst22=J(CH)
"d5=2.7m-p11-3u-4u-p16-d16"         
"d22=3.6m"                           ;k
"d58=5.4m"                           ;k1                     
"d6=d15-d22"
"d11=30m"
"d14=p14"
"d16=180u"

;############### center pulses ################

"d3=p21-p1"
"d8=(p14-p21*2)*0.5"


;#########################

"d10=3u"                             
"d20=d10+d14+d7+d8"                    

;############### incremented time t1 ##########
"d9=d14+d7+3u"                         ;t1/2 decreased 
"d0=3u"                            ;t1/2 increased
"d21=d8*2+d7+p21*2-d58-p1-24u"

"in9=in0"


"spoff2=0"
"spoff3=0"
"spoff4=0"
"spoff5=bf2*(cnst21/1000000)-o2"



1 ze
  d11 pl16:f3
2 d11 do:f3
3 d11
  d1 
  50u UNBLKGRAD
  d12 pl1:f1 pl0:f2 pl3:f3
  (p1 ph1)
  d4
  (center (p1*2 ph1):f1 (p14:sp3 ph1):f2)  
  d4
  (center (p1 ph9):f1 (p13:sp2 ph11):f2)    
  d22
  (p1 ph9 20u pl19 4u cpds1):f1
  d6
  (center (p21*2 ph1):f3 (p34:sp20 ph1):f2)   ;p34 is the crucial pulse
  d15                                  
  (p13:sp4 ph0):f2        
  4u do:f1
  20u pl1:f1
  (p1 ph10):f1
  4u
  p16:gp3
  d16
  (p1 ph9):f1
  3u
  20u pl19:f1
  4u cpds1:f1
  (p21 ph8):f3
  5u
  
;#### Start t1 d0=F ; d9=D=15m-3u ; d7=E=15m ; d58=5.4m=k1 #########

  d9
  (d21 d0 4u do 20u pl1 p1 ph10):f1 (p14:sp3 ph0 d7 p14:sp5 ph0 d0):f2 (d8 p21*2 ph0 d8 d7 d14 d0):f3

;######## end t1 ##############

  (p21 ph0):f3     
  4u
  p16:gp5
  d16
  (p11:sp1 ph3:r):f1
  10u
  20u pl1:f1
  (p1 ph0):f1
  3u
  p16:gp4
  d16
  4u
  d5 pl11:f1                          
  (p11:sp1 ph4:r):f1
  3u
  20u pl1:f1
  (d3 p1*2 ph5) (p21*2 ph0):f3
  3u
  20u pl11:f1
  (p11:sp1 ph4:r):f1
  3u
  d5                                  
  p16:gp4
  d16 pl16:f3
  4u BLKGRAD
  go=2 ph31 cpd3:f3
  d11 do:f3 mc #0 to 2
  F1PH(ip8, dd9 & id0)
exit

ph0=0
ph1=0 
ph2=0 2         
ph3=2
ph4=0
ph5=2
ph7=0
ph8=0 0 2 2 
ph9=1
ph10=3
ph11=0 2
ph31=0 2 2 0


;p34: (tune this pulse for A, S/T) f2 180 degree 13C shape
;sp20: f2 power 180 (CA)
;spnam9: try different shapes for inversion
;spoff9: optimize on offset
;d1: relaxation delay; 1-5*T1
;d11: delay for disk I/O [30 msec]
;pl1: f1 power H high power pulse
;p1: f1 90 degree high power pl1 pulse
;d2: 2.25-2.75m (Jhn=92Hz)
;d3: p21-p1 (center pulse)
;cnst22:140 Hz (J(CH))
;d4:1s/(cnst22*4)
;pl2: f2 power C13 hard pulse (not used)
;pl3: f3 power N15 hard pulse
;p21: f3 90 degree high power N15 high power pl3 pulse
;pl11: f1 power H2O soft rectangular pulse (1m)
;p28: f1 90 degree H2O low power pl11 rectangluar pulse
;p13: 90 degree 13C shape
;p14: 180 degree 13C shape
;gpz1: 30%
;gpnam1: sine.100 shape of gradient pulse
;sp5: f2 power 180 (CA) soft shaped
;p14: f2 soft shaped pulse 180 null at 18200 Hz
;spnam5: use shape G3.256
;spoff5: use offset 18200.0 Hz (600 MHz) on CO, null CA
;spnam3: use shape G3.256
;spoff3: use offset 0.0 Hz (600 MHz) on CA, null CO
;d22: 3.6m (k in sequence)
;pl19: f1 power for cpds1 decoupling
;cpd1: dipsi2 (along x)
;pcpd3: f1 cpds1 pulse length (60-70u) use 65u
;d0: t1/2
;d7: Tn [12-16m] use 15m
;d9: d0+d14+d7+d8 (Tn-t1/2) SET ALWAYS d9<=d8+3u
;gpz2: 30 % power level
;gpnam2: sine.100 shape of gradient pulse
;sp2: f2 power 90 (CA) soft shaped
;spnam2: use shape G4.256
;spoff2: use offset 0.0 on CA, null CO
;sp4: f2 power 90 (CA) soft shaped
;spnam4: use shape G4.256tr (time reverse shape)
;spoff4: use offset 0.0 on CA, null CO
;d15: [12-18m] Tcn, use 12m
;gpz3: 30%
;gpnam3: sine.100 shape of gradient pulse
;d20: t2/2 (Tn-t2/2) [d9-d8]
;d10: t2/2
;sp1: f1 power H2O soft shaped pulse
;p11: (2m) half-gaussian soft pulse with power sp1
;spnam1: hg.1000 half gaussian shape
;p16: gradient pulse 1 ms
;gpz4: 80 %
;gpnam4: sine.100 shape of gradient pulse
;d4: 2.7m-p2-3u-4u-p16-d16
;pl16: f3 power level N15 cpd decoupling
;cpd3: cpdprg3 decoupling sequence [garp]
;pcpd3: f3 decoupling 90 degree pulse [>170 u]
;l1: td1/2 STATES/TPPI
;in0: 1/(2* SW(N15)) = DW(N15)
;in9: SET ALWAYS in9=in0
;nd0: 2
;NS: 8*n
;DS: 16
;td1: number of experiments N15
;MC2: STATES-TPPI